您当前的位置: 首页 » AMPZ/Nginx/IIS发布安装 » 用批处理删除7天以前的备份文件
用批处理删除7天以前的备份文件
论坛链接
::删除F:\文件备份里的 7天前的txt文件
::被删除的文件日期以文件创建日期为主
@echo off
::取7天之前的日期.
>tmp.vbs echo wscript.echo dateadd("d",-7,date)
for /f "tokens=1,2,3* delims=-" %%i in ('cscript /nologo tmp.vbs') do (
set y=%%i
set m=%%j
set d=%%k
)
if %m% LSS 10 set m=0%m%
if %d% LSS 10 set d=0%d%
set rq=%y%-%m%-%d%
echo 注意:即将删除 %rq% 以前建立的文件
pause
::判断文件
for /f "skip=4 delims=" %%i in ('dir/tc F:\文件备份\*.txt') do call :w "%%i"
del tmp.vbs
goto :eof
:w
for /f "tokens=4 delims= " %%a in (%1) do set str=%%a
set var=%1
set num=%var:~1,10%
if %num% lss %rq% del /q F:\文件备份\%str%
::被删除的文件日期以文件创建日期为主
@echo off
::取7天之前的日期.
>tmp.vbs echo wscript.echo dateadd("d",-7,date)
for /f "tokens=1,2,3* delims=-" %%i in ('cscript /nologo tmp.vbs') do (
set y=%%i
set m=%%j
set d=%%k
)
if %m% LSS 10 set m=0%m%
if %d% LSS 10 set d=0%d%
set rq=%y%-%m%-%d%
echo 注意:即将删除 %rq% 以前建立的文件
pause
::判断文件
for /f "skip=4 delims=" %%i in ('dir/tc F:\文件备份\*.txt') do call :w "%%i"
del tmp.vbs
goto :eof
:w
for /f "tokens=4 delims= " %%a in (%1) do set str=%%a
set var=%1
set num=%var:~1,10%
if %num% lss %rq% del /q F:\文件备份\%str%
#2楼发布者：superadmin时间：2009-03-05 14:21:39
公司服务器用来备份数据的硬盘过段时间就会被备份文件占满，弄得我老是要登录到服务器去手工删除那些老的文件，有时忘记了就会导致硬盘空间不足而无法备份。
因为只要保留最近几天的备份，如果可以做一个批处理让系统自动删除老备份文件就好了，但是Windows的命令行和Linux的Shell比起来功能差了很多，到底行不行我自己也不清楚。
于是上网查了一下各位大虾发的帖子，再经过自己的摸索和尝试，发现只要花点功夫还是能实现这个功能的。
下面来看看我的实现方法。
如果操作系统是 Windows Server 2003 那就好办了，因为它有一个forfiles命令能够查找满足指定条件的文件，下面是这个命令的用法。
forfiles /p <目标目录名> /d <天数> /c <执行的命令>
看看列出的三个参数都有什么用处：
/p 指定了要在哪个目录里查找文件，默认是当前工作目录。
/d 指定一个日期或天数，用于比较文件的最后修改日期是否符合条件。
/c 对每个找到的文件执行的命令。
例1.要把在C盘根目录下最后修改日期大于或等于2007年7月1日的文件复制到D盘根目录下：
forfiles /p "c:\" /d "2007-7-1" /c "cmd /c copy @path d:\"
例2.删除在C盘backup目录下最后修改日期在10天前的文件：
forfiles /p "c:\backup" /d -10 /c "cmd /c echo deleting @file ... && del /f @path"
看了上面的例子，觉得在 Windows Server 2003 下面要删除老文件很简单吧。
但如果操作系统是 Windows 2000/XP 就比较麻烦，因为它们没有forfiles命令，只能靠自己写批处理来实现了。
下面是我写的批处理文件内容：
@echo off
rem ******************************
rem * 按时间删除文件目录的批处理 *
rem ******************************
rem 设置临时目录的路径
set tempDir=%tmp%\remove_%date:~0,10%
if not exist %tempDir% md %tempDir%
rem 设置处理日期的脚本文件的路径
set scriptFile=%tempDir%\get_date.vbs
rem 获得要保留的天数
set days=%~1
if "%days%" == "" goto printUsage
rem 获得目标目录的路径
set dirPath=%~2
if "%dirPath%" == "" set dirPath=.
rem 获得要操作的文件形式
set fileSpec=%~3
if "%fileSpec%" == "" set fileSpec=*.*
rem 生成计算日期的脚本文件并获得删除的截止日期
echo d=date()-%1 > %scriptFile%
echo s=right("0000" ^& year(d),4) ^& "-" ^& right("00" ^& month(d),2) ^& "-" ^& right("00" ^& day(d),2) >> %scriptFile%
echo wscript.echo s >> %scriptFile%
for /f %%i in ('cscript /nologo %scriptFile%') do set lastDate=%%i
rem 处理目标目录里的每个对象
for /f "tokens=1,2,3* delims=<> " %%i in ('dir "%dirPath%\%fileSpec%" /a /-c /tc') do call :proc "%%i" "%%j" "%%k" "%%l"
goto :done
rem 处理目标目录里对象的过程
:proc
rem 获得对象的创建日期并判断是否为有效格式
set fileDate=%~1
echo %fileDate% | findstr "[0-9][0-9][0-9][0-9]-[0-9][0-9]-[0-9][0-9]" > nul
if errorlevel 1 goto end
rem 获得对象的类型
set fileType=%~3
if "%fileType%" == "" goto end
rem 获得对象的名称
set fileName=%~4
if "%fileName%" == "" goto end
if "%fileName%" == "." goto end
if "%fileName%" == ".." goto end
if "%fileName%" == "字节" goto end
if "%fileName%" == "可用字节" goto end
rem 判断对象日期是否小于或等于删除的截止日期
if "%fileDate:~0,10%" leq "%lastDate%" (
echo deleting "%fileName%" ...
if "%fileType%" == "DIR" ( rd /s /q "%dirPath%\%fileName%" ) else ( del /q /f "%dirPath%\%fileName%" )
)
goto end
:error
echo An error occurred during backuping.
:done
rd /s /q %tempDir%
goto end
:printUsage
echo Usage: %0 ^<Days^> [Work directory] [Target file specification (can include wildcards)]
goto end
:end
这个批处理的语句很多，我表达能力有限，懒得一一解释了。
主要是利用Windows的脚本功能来计算要删除文件的截止日期，然后for加dir命令来提取文件的日期进行判断。
关于forfiles和for的详细信息，可以在Windows的帮助与支持中找到。
因为只要保留最近几天的备份，如果可以做一个批处理让系统自动删除老备份文件就好了，但是Windows的命令行和Linux的Shell比起来功能差了很多，到底行不行我自己也不清楚。
于是上网查了一下各位大虾发的帖子，再经过自己的摸索和尝试，发现只要花点功夫还是能实现这个功能的。
下面来看看我的实现方法。
如果操作系统是 Windows Server 2003 那就好办了，因为它有一个forfiles命令能够查找满足指定条件的文件，下面是这个命令的用法。
forfiles /p <目标目录名> /d <天数> /c <执行的命令>
看看列出的三个参数都有什么用处：
/p 指定了要在哪个目录里查找文件，默认是当前工作目录。
/d 指定一个日期或天数，用于比较文件的最后修改日期是否符合条件。
/c 对每个找到的文件执行的命令。
例1.要把在C盘根目录下最后修改日期大于或等于2007年7月1日的文件复制到D盘根目录下：
forfiles /p "c:\" /d "2007-7-1" /c "cmd /c copy @path d:\"
例2.删除在C盘backup目录下最后修改日期在10天前的文件：
forfiles /p "c:\backup" /d -10 /c "cmd /c echo deleting @file ... && del /f @path"
看了上面的例子，觉得在 Windows Server 2003 下面要删除老文件很简单吧。
但如果操作系统是 Windows 2000/XP 就比较麻烦，因为它们没有forfiles命令，只能靠自己写批处理来实现了。
下面是我写的批处理文件内容：
@echo off
rem ******************************
rem * 按时间删除文件目录的批处理 *
rem ******************************
rem 设置临时目录的路径
set tempDir=%tmp%\remove_%date:~0,10%
if not exist %tempDir% md %tempDir%
rem 设置处理日期的脚本文件的路径
set scriptFile=%tempDir%\get_date.vbs
rem 获得要保留的天数
set days=%~1
if "%days%" == "" goto printUsage
rem 获得目标目录的路径
set dirPath=%~2
if "%dirPath%" == "" set dirPath=.
rem 获得要操作的文件形式
set fileSpec=%~3
if "%fileSpec%" == "" set fileSpec=*.*
rem 生成计算日期的脚本文件并获得删除的截止日期
echo d=date()-%1 > %scriptFile%
echo s=right("0000" ^& year(d),4) ^& "-" ^& right("00" ^& month(d),2) ^& "-" ^& right("00" ^& day(d),2) >> %scriptFile%
echo wscript.echo s >> %scriptFile%
for /f %%i in ('cscript /nologo %scriptFile%') do set lastDate=%%i
rem 处理目标目录里的每个对象
for /f "tokens=1,2,3* delims=<> " %%i in ('dir "%dirPath%\%fileSpec%" /a /-c /tc') do call :proc "%%i" "%%j" "%%k" "%%l"
goto :done
rem 处理目标目录里对象的过程
:proc
rem 获得对象的创建日期并判断是否为有效格式
set fileDate=%~1
echo %fileDate% | findstr "[0-9][0-9][0-9][0-9]-[0-9][0-9]-[0-9][0-9]" > nul
if errorlevel 1 goto end
rem 获得对象的类型
set fileType=%~3
if "%fileType%" == "" goto end
rem 获得对象的名称
set fileName=%~4
if "%fileName%" == "" goto end
if "%fileName%" == "." goto end
if "%fileName%" == ".." goto end
if "%fileName%" == "字节" goto end
if "%fileName%" == "可用字节" goto end
rem 判断对象日期是否小于或等于删除的截止日期
if "%fileDate:~0,10%" leq "%lastDate%" (
echo deleting "%fileName%" ...
if "%fileType%" == "DIR" ( rd /s /q "%dirPath%\%fileName%" ) else ( del /q /f "%dirPath%\%fileName%" )
)
goto end
:error
echo An error occurred during backuping.
:done
rd /s /q %tempDir%
goto end
:printUsage
echo Usage: %0 ^<Days^> [Work directory] [Target file specification (can include wildcards)]
goto end
:end
这个批处理的语句很多，我表达能力有限，懒得一一解释了。
主要是利用Windows的脚本功能来计算要删除文件的截止日期，然后for加dir命令来提取文件的日期进行判断。
关于forfiles和for的详细信息，可以在Windows的帮助与支持中找到。